# Using autorevision.sh to generate version information

set(__SOURCE_AUTORESIVISION ${CMAKE_SOURCE_DIR}/autorevision.sh)
set(__AUTORESIVISION ${CMAKE_BINARY_DIR}/autorevision.sh)
set(__VERSION_CACHE ${CMAKE_SOURCE_DIR}/version.txt)
set(__VERSION_CONFIG ${CMAKE_BINARY_DIR}/version.cmake)
set(__VERSION_CONFIG_C_IN ${CMAKE_SOURCE_DIR}/include/internal/mr_version.h.in)
set(__VERSION_CONFIG_C_OUT ${CMAKE_BINARY_DIR}/include/internal/mr_version.h)

file(COPY ${__SOURCE_AUTORESIVISION} DESTINATION ${CMAKE_BINARY_DIR}
	FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE
	WORLD_READ WORLD_EXECUTE)

# execute autorevision.sh to generate version information
execute_process(COMMAND ${__AUTORESIVISION} -t cmake -o ${__VERSION_CACHE} 
				OUTPUT_FILE ${__VERSION_CONFIG} ERROR_QUIET)
include(${__VERSION_CONFIG})

# generate c header file
configure_file(${__VERSION_CONFIG_C_IN} ${__VERSION_CONFIG_C_OUT} @ONLY)
add_definitions(-include ${__VERSION_CONFIG_C_OUT})

# extract major, minor, patch version from git tag
string(REGEX REPLACE "^v([0-9]+)\\..*" "\\1" MARSIO_VERSION_MAJOR "${VCS_TAG}")
string(REGEX REPLACE "^v[0-9]+\\.([0-9]+).*" "\\1" MARSIO_VERSION_MINOR "${VCS_TAG}")
string(REGEX REPLACE "^v[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" MARSIO_VERSION_PATCH "${VCS_TAG}")

if(NOT MARSIO_VERSION_MAJOR)
	set(MARSIO_VERSION_MAJOR 4)
endif()

if(NOT MARSIO_VERSION_MINOR)
	set(MARSIO_VERSION_MINOR 0)
endif()

if(NOT MARSIO_VERSION_PATCH)
	set(MARSIO_VERSION_PATCH 0)
endif()

set(MARSIO_VERSION "${MARSIO_VERSION_MAJOR}.${MARSIO_VERSION_MINOR}.${MARSIO_VERSION_PATCH}")
set(MARSIO_VERSION_BUILD "${VCS_SHORT_HASH}")

# system information
execute_process(COMMAND uname -r OUTPUT_VARIABLE MARSIO_VERSION_KERNEL)

# print information
message(STATUS "Marsio Version: ${MARSIO_VERSION}-${MARSIO_VERSION_BUILD}")
message(STATUS "Kernel Version: ${MARSIO_VERSION_KERNEL}")

set(MARSIO_GIT_VERSION "${MARSIO_VERSION}-${MARSIO_VERSION_BUILD}")
add_definitions(-DGITVER=\"${MARSIO_GIT_VERSION}\")